//Brain code.  Finds a maximum using genetic optimization.

int bounds=500;
int bg=150;
int diam=5;
int timeindex=1;
int paramnum=2;
int genepool=300;
float mutate=.2;

float[][] z = new float[genepool][paramnum];
float[] delt = new float[paramnum];
float[] util = new float[genepool];
float[] c1 = new float[paramnum];
float[] c2 = new float[paramnum];
float utilc1=1;
float utilc2=1;
float sexprob=1;

//z is an array which will house all parameters of the system, which we vary to find a maximum.
//delt tells us how much we're varying each parameter at a given time.
//currently, z just houses the x and y coordinates of a point on the screen, but z can really be any parameter that we can control.


void setup(){
  for (int i=0;i<genepool;i++){
    for(int j=0;j<paramnum;j++){
      z[i][j]=random(bounds);
    }
    util[i]=1;
  }
  for (int i=0;i<paramnum;i++){
    delt[i]=mutate;
    c1[i]=250;
    c2[i]=250;
  }
  size(bounds,bounds); 
  background(bg);
  PFont font;
  font = loadFont("Monaco-9.vlw"); 
  textFont(font, 9);
}

void mousePressed(){
  background(bg);
  for (int i=0;i<genepool;i++){
    for(int j=0;j<paramnum;j++){
      z[i][j]=random(bounds);
    }
    util[i]=1;
  }
  for (int i=0;i<paramnum;i++){
    delt[i]=mutate;
    c1[i]=250;
    c2[i]=250;
  }
  timeindex=1;
}

void drawbox(){
  background(bg);
//  ellipse(bounds/4,bounds/4,2*diam,2*diam);
//  ellipse(3*bounds/4,bounds/4,2*diam,2*diam);
//  ellipse(bounds/4,3*bounds/4,2*diam,2*diam);
//  ellipse(3*bounds/4,3*bounds/4,2*diam,2*diam);
  
  for (int i=0;i<genepool;i++){
    line(z[i][0]+diam,z[i][1]+diam,z[i][0]+diam,z[i][1]-diam);
    line(z[i][0]+diam,z[i][1]-diam,z[i][0]-diam,z[i][1]-diam);
    line(z[i][0]-diam,z[i][1]-diam,z[i][0]-diam,z[i][1]+diam);
    line(z[i][0]-diam,z[i][1]+diam,z[i][0]+diam,z[i][1]+diam);
  }
}

//The utility function.  This is the function that this program attempts to maximize.  It should depend on each parameter in the z array.
//If this is a guy's brain, the utility function gives him motivation.

float utilget(float x, float y){
//  float level=sin(2*3.14*abs(x-bounds/2)/bounds)*sin(2*3.14*abs(y-bounds/2)/bounds);
  float level=sin(5*atan2((y-bounds/2),(x-bounds/2)))*sin(8*3.14*sqrt((x-bounds/2)*(x-bounds/2)+(y-bounds/2)*(y-bounds/2))/bounds); //*exp(-((x-3*bounds/4)*(x-3*bounds/4)+(y-3*bounds/4)*(y-3*bounds/4))/bounds/bounds);
  return(level);
}

void draw(){
  
  
  //First, find the utility of each position.
  
  drawbox();
  for (int i=0;i<genepool;i++){
    util[i]=utilget(z[i][0],z[i][1]);
    text(util[i],z[i][0]+diam,z[i][1]+diam);
  }
  
  //Everyone picks someone to procreate with.  Currently, this could include self, need to do more maths.
  
  for (int i=0;i<genepool;i++){
    if (random(1)<sexprob){
      int j=floor(random(genepool));
      
      line(z[i][0],z[i][1],z[j][0],z[j][1]);
      
      //Pick two random points along the line between i and j.
      float r1=random(1);
      float r2=random(1);
      for (int k=0;k<paramnum;k++){
        c1[k]=r1*z[i][k]+(1-r1)*z[j][k];
        c2[k]=r2*z[i][k]+(1-r2)*z[j][k];
        //mutate c1 and c2
        c1[k]=c1[k]+random(2*delt[k])-delt[k];
        c2[k]=c2[k]+random(2*delt[k])-delt[k];        
      }
      utilc1=utilget(c1[0],c1[1]);
      utilc2=utilget(c2[0],c2[1]);
      
      if (r1<r2){      
        if (utilc1>util[i]){
          for(int k=0;k<paramnum;k++){
            z[i][k]=c1[k];
          }
        }
        if (utilc2>util[j]){
          for(int k=0;k<paramnum;k++){
            z[j][k]=c2[k];
          }
        }
      }else{
        if (utilc1>util[j]){
          for(int k=0;k<paramnum;k++){
            z[j][k]=c1[k];
          }
        }
        if (utilc2>util[i]){
          for(int k=0;k<paramnum;k++){
            z[i][k]=c2[k];
          }
        }
      }
    }
  }
  
  text(timeindex,bounds-150,50);
  timeindex++;
}